home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / EDIT0.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-12-13  |  4.0 KB  |  109 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * FILE I/O ROUTINES  
  14.  
  15.     xref    open_w,lineed,printf,read_in,prompt
  16.     xref    write_out,set_w,ask,cmd_w
  17.     xdef    readfile,writefile,filenm
  18.  
  19. #edit.h
  20.  
  21. *****************************************************************
  22. * Asks for a filename and reads it into current editing buffer
  23. * ENTRY:   A5.L points to edit buffer window descriptor file
  24. *          sets ed_err(a5) on error
  25. readfile:
  26.     movem.l    d1/d2/a0-a5,-(a7) Save caller's registers
  27.     move.l    #fprompt,a0    * setup prompt address
  28.     move.l    #filenm,a1    * setup input string address
  29.     bsr    ask        * output prompt
  30.     move.l    #filenm,a0    * setup for file read
  31.     move.l    b_gap(a5),a2    * save current start of gap
  32.     bsr    read_in        * try to read file
  33.     move.l    b_gap(a5),a3    * get new start of gap
  34.     move.l    a2,b_gap(a5)    * save gap start point
  35.  
  36.     move.l    a3,d1        * check how many chars read
  37.     sub.l    a2,d1        * d1 is now number of chars read
  38.     move.l    e_gap(a5),a2    * get end of gap address
  39.     bra    loop_test    * this is a check-first loop
  40. loop_point:
  41.     move.b    -(a3),-(a2)    * transfer chars to end of gap
  42. loop_test:
  43.     dbra    d1,loop_point
  44.     move.l    a2,e_gap(a5)    * save new gap end address
  45.     tst.w    d0        * check if file was read
  46.     beq    exit        * just leave if we read it
  47.     cmp.b    #1,d0        * is it file-not-found error?
  48.     beq    sk0_rf        * yes, go tell user
  49.     move.w    #5,ed_err(a5)    * was file-too-large error
  50.     bra    exit        * print error
  51. sk0_rf:
  52.     move.w    #6,ed_err(a5)    * new file message address
  53. exit:
  54.     movem.l    (a7)+,d1/d2/a0-a5 * restore caller's registers
  55.     rts
  56. fprompt:
  57.     dc.b    'Input Filename: ',0
  58.     dc.w    0
  59. *****************************************************************
  60. * WRITEFILE - writes a block to disk
  61. *  ENTRY: A1.L points to start of data buffer
  62. *         D1.W holds number of bytes to write
  63. *  EXIT:  D0.W = 0 for success
  64. *              = 1 for failure
  65. writefile:
  66.     movem.l    d1/d2/a0/a5,-(a7) * Save caller's registers
  67.     move.l    #cmd_w,a5    * get command I/O window desc.
  68.     bsr    open_w        * open command window
  69.     move.w    w_ulcy(a5),-(a7) * setup prompt Y position
  70.     move.w    w_ulcx(a5),-(a7) * setup prompt X position
  71.     move.l    #wprompt,-(a7)    * setup prompt address
  72.     bsr    printf        * output prompt
  73.     addq.l    #8,a7        * fix the stack
  74.     move.w    w_ulcx(a5),d0    * input line X position
  75.     add.w    #17,d0        * new X position for input line
  76.     move.w    w_lrcx(a5),d2    * calculate max. line length for
  77.     sub.w    d0,d2        *... input line editor
  78.     move.w    d2,-(a7)    * push max editing lines
  79.     move.w    d0,-(a7)    * push starting screen column
  80.     move.w    w_ulcy(a5),-(a7) * push screen row
  81.     move.l    #filenm,-(a7)    * push string address
  82.     bsr    lineed        * get input line with filename
  83.     add.l    #10,a7        * pop lineed parameters
  84.     
  85.     move.l    #filenm,a0    * setup for file write
  86.     bsr    write_out    * try to read file
  87.     tst.w    d0        * check if file was written
  88.     beq    wexit        * just leave if we wrote it
  89.     move.w    w_ulcy(a5),-(a7) * push message y position - 1
  90.     addq.w    #1,(a7)        * adjust for correct position
  91.     move.w    w_ulcx(a5),-(a7) * push x position
  92.     move.l    #cant_rite,-(a7) * push message string address
  93.     bsr    printf        * tell user
  94.     addq.l    #8,a7        * fix stack
  95.     move.w    #1,d0        * set error code
  96. wexit:
  97.     movem.l    (a7)+,d1/d2/a0/a5 * restore caller's registers
  98.     rts
  99. wprompt:
  100.     dc.b    '%vOutput Filename: ',0
  101. cant_rite:
  102.     dc.b    '%v* * * Error writing file * * *',0
  103.     dc.w    0
  104. *****************************************************************
  105.     bss
  106. filenm:    ds.b    80        * current filename buffer
  107.  
  108.     end
  109.